[@main]
#IF
IsAdmin
#SAY
┏━<游戏说明/@游戏说明>━┓ 〓〓〓〓〓〓〓<激烈的斗鸡比赛>〓〓<初始化/@初始化>〓〓 \
┃ ┃【<$USERNAME>】你所拥有的元宝：【<$GAMEGOLD>】 \
┃ <我来坐庄/@@InPutInteger36> ┃ <$STR(A60)>本钱：【<$STR(I25)>】\
┃ ┃ 压注甲方的总共人数：【<$STR(I15)>】 \
┃ <压注甲方/@@InPutInteger30> ┃ 压注乙方的总共人数：【<$STR(I17)>】 \
┃ ┃ 压注甲方的总元宝数：【<$STR(I14)>】 \
┃ <压注乙方/@@InPutInteger32> ┃ 压注乙方的总元宝数：【<$STR(I16)>】 \
┃ ┃ 你将【<$STR(N34)>】个元宝下注在【<$STR(S23)>】 \
┗━<返回盟重/@返回盟重>━┛ 开始斗鸡比赛还差【<$STR(I10)>】秒 <甲/@甲> <乙/@乙> <刷新/@MAIN> <$STR(I20)> <$STR(I24)>\
#ELSESAY
┏━<游戏说明/@游戏说明>━┓ 〓〓〓〓〓〓〓<激烈的斗鸡比赛>〓〓〓〓〓〓〓 \
┃ ┃【<$USERNAME>】你所拥有的元宝：【<$GAMEGOLD>】 \
┃ <我来坐庄/@@InPutInteger36> ┃ <$STR(A60)>本钱：【<$STR(I25)>】\
┃ ┃ 压注甲方的总共人数：【<$STR(I15)>】 \
┃ <压注甲方/@@InPutInteger30> ┃ 压注乙方的总共人数：【<$STR(I17)>】 \
┃ ┃ 压注甲方的总元宝数：【<$STR(I14)>】 \
┃ <压注乙方/@@InPutInteger32> ┃ 压注乙方的总元宝数：【<$STR(I16)>】 \
┃ ┃ 你将【<$STR(N34)>】个元宝下注在【<$STR(S23)>】 \
┗━<返回盟重/@返回盟重>━┛ 开始斗鸡比赛还差【<$STR(I10)>】秒 <刷新/@MAIN>\
[@甲]
#IF
IsAdmin
#ACT
MOV I20 1
GOTO @main
SENDMSG 6 将甲方的胜率提升了！！！！！！！！
[@乙]
#IF
IsAdmin
#ACT
MOV I20 2
GOTO @main
SENDMSG 6 将乙方的胜率提升了！！！！！！！！
[@返回盟重]
#IF
#ACT
MapMove 3 330 330
BREAK
[@InPutInteger36]
#IF
CheckLevelEx > 0
#ACT
MOVR N25 100 3000
DelayGoto <$str(N25)> @Integer36
[@Integer36]
#IF
EQUAL I32 1
#ACT
MOV N36 0
SendMSG 5 [提示]：别人正在下注。请等待再下注！
#ELSEACT
MOV I32 1
GOTO ~Integer36
DelayGoto 500 @jiekai36
[@jiekai36]
#ACT
MOV I32 0
[~Integer36]
#IF
SMALL I18 3
#ACT
MOV N36 0
MOV I32 0
SENDMSG 5 [提示]：抢庄时间已经结束。你可以下注或等待新开局！
GOTO @main
BREAK
#IF
EQUAL A61 <$USERNAME>
#ACT
MOV N36 0
MOV I32 0
SENDMSG 5 [提示]：你目前已经是庄家，无法重复坐庄。
GOTO @main
BREAK
#IF
EQUAL M44 2
#ACT
MOV N36 0
MOV I32 0
SENDMSG 5 [提示]：你已经下注甲方，无法再抢庄！
GOTO @main
BREAK
#IF
EQUAL M44 3
#ACT
MOV N36 0
MOV I32 0
SENDMSG 5 [提示]：你已经下注乙方，无法再抢庄！
GOTO @main
BREAK
#IF
SMALL N36 100
#ACT
SENDMSG 5 [提示]：请输入100以上的数值！
MOV N36 0
MOV I32 0
GOTO @main
BREAK
#IF
CHECKGAMEGOLD < <$STR(N36)>
#ACT
SENDMSG 5 [提示]：你身上的元宝不足。
MOV N36 0
MOV I32 0
GOTO @main
BREAK
#IF
EQUAL I25 0
#ACT
GAMEGOLD - <$STR(N36)>
MOV I25 <$STR(N36)>
MOV I26 <$STR(N36)>
MOV I27 <$STR(N36)>
MOV A61 <$USERNAME>
MOV A60 现在的庄家是【
INC A60 <$STR(A61)>
INC A60 】
MOV I32 0
SendMSG 0 %s 使用<$STR(N36)>个元宝坐庄。
SendMSG 0 有<$STR(I18)>秒的抢庄时间，需要抢庄的抓紧时间!<$STR(I18)>秒后闲家开始下注！
SENDMSG 5 [提示]：使用【<$STR(N36)>】个元宝坐庄。
MOV N36 0
GOTO @main
BREAK
#IF
LARGE N36 <$STR(I25)>
#ACT
MOV I35 <$STR(I25)>
MOV A64 <$STR(A61)>
HCall <$STR(A64)> @斗鸡被人抢庄
GAMEGOLD - <$STR(N36)>
MOV I25 <$STR(N36)>
MOV I26 <$STR(N36)>
MOV I27 <$STR(N36)>
MOV A61 <$USERNAME>
MOV A60 现在的庄家是【
INC A60 <$STR(A61)>
INC A60 】
MOV I32 0
SendMSG 0 %s 使用<$STR(N36)>个元宝抢得斗鸡比赛的庄家！
SENDMSG 5 [提示]：使用【<$STR(N36)>】个元宝抢庄成功。
MOV N36 0
GOTO @main
BREAK
#ELSEACT
SENDMSG 5 [提示]：你必须出多于【<$STR(I25)>】个元宝才能抢庄。
MOV N36 0
MOV I32 0
GOTO @main
BREAK
[@InPutInteger30]
#IF
CheckLevelEx > 0
#ACT
MOVR N25 100 3000
DelayGoto <$str(N25)> @Integer30
[@Integer30]
#IF
EQUAL I33 1
#ACT
MOV N30 0
SendMSG 5 [提示]：别人正在下注。请等待再下注！
#ELSEACT
MOV I33 1
GOTO ~Integer30
DelayGoto 500 @jiekai30
[@jiekai30]
#ACT
MOV I33 0
[~Integer30]
#IF
LARGE I18 0
#ACT
MOV N30 0
MOV I33 0
SENDMSG 5 [提示]：现在是抢庄时间，稍等一下才能下注！
GOTO @main
BREAK
#IF
EQUAL A61 <$USERNAME>
#ACT
MOV N30 0
MOV I33 0
SENDMSG 5 [提示]：你目前已经是庄家，不能在闲家下注！
GOTO @main
BREAK
#IF
SMALL I10 3
#ACT
MOV N30 0
MOV I33 0
SENDMSG 5 [提示]：下注时间已过，不能下注，等这把斗完才能下注！
GOTO @main
BREAK
#IF
LARGE N30 <$STR(I26)>
#ACT
MOV N30 0
MOV I33 0
SENDMSG 5 [提示]：对不起，庄家的本钱已达到上限不够赔了。\目前你只可以下注【<$STR(I26)>】以下的元宝！
GOTO @main
BREAK
#IF
SMALL N30 10
#ACT
SENDMSG 5 [提示]：下注下限不能少于10个元宝,请重新下注！
MOV N30 0
MOV I33 0
GOTO @main
BREAK
#IF
LARGE N30 <$STR(I25)>
#ACT
SENDMSG 5 [提示]：下注上限不能多过10000个元宝,请重新下注！
MOV N30 0
MOV I33 0
GOTO @main
BREAK
#IF
CHECKGAMEGOLD < <$STR(N30)>
#ACT
SENDMSG 5 [提示]：你身上的元宝不足。
MOV N30 0
MOV I33 0
GOTO @main
BREAK
#IF
EQUAL M44 3
#ACT
MOV N30 0
MOV I33 0
SENDMSG 5 [提示]：你已经下注乙方，不能在甲方下注了！
GOTO @main
BREAK
#IF
EQUAL M44 2
#ACT
MOV N30 0
MOV I33 0
SENDMSG 5 [提示]：你已经下注甲方，不能在甲方重复下注！
GOTO @main
#ELSEACT
MOV S23 甲方
MOV M44 2
MOV N31 <$STR(N30)>
MOV N34 <$STR(N31)>
GAMEGOLD - <$STR(N34)>
INC I14 <$STR(N31)>
INC I15 1
DEC I26 <$STR(N31)>
MOV I8 1
MOV I33 0
MOV N30 0
SENDMSG 6 你将<$STR(N34)>个元宝下注到【<$STR(S23)>】！祝你好运！！
GOTO @MAIN
[@InPutInteger32]
#IF
CheckLevelEx > 0
#ACT
MOVR N25 100 3000
DelayGoto <$str(N25)> @Integer32
[@Integer32]
#IF
EQUAL I34 1
#ACT
MOV N32 0
SendMSG 5 [提示]：别人正在下注。请等待再下注！
#ELSEACT
MOV I34 1
GOTO ~Integer32
DelayGoto 500 @jiekai32
[@jiekai32]
#ACT
MOV I34 0
[~Integer32]
#IF
LARGE I18 0
#ACT
MOV N32 0
MOV I34 0
SENDMSG 5 [提示]：现在是抢庄时间，稍等一下才能下注！
GOTO @main
BREAK
#IF
EQUAL A61 <$USERNAME>
#ACT
MOV N32 0
MOV I34 0
SENDMSG 5 [提示]：你目前已经是庄家，不能在闲家下注！
GOTO @main
BREAK
#IF
SMALL I10 3
#ACT
MOV N32 0
MOV I34 0
SENDMSG 5 [提示]：下注时间已过，不能下注，等这把斗完才能下注！
GOTO @main
BREAK
#IF
LARGE N32 <$STR(I27)>
#ACT
MOV N32 0
MOV I34 0
SENDMSG 5 [提示]：对不起，庄家的本钱已达到上限不够赔了。\目前你只可以下注【<$STR(I27)>】以下的元宝！
GOTO @main
BREAK
#IF
SMALL N32 10
#ACT
SENDMSG 5 [提示]：下注下限不能少于10个元宝,请重新下注！
MOV N32 0
MOV I34 0
GOTO @main
BREAK
#IF
LARGE N32 <$STR(I25)>
#ACT
SENDMSG 5 [提示]：下注上限不能多过10000个元宝,请重新下注！
MOV N32 0
MOV I34 0
GOTO @main
BREAK
#IF
CHECKGAMEGOLD < <$STR(N32)>
#ACT
SENDMSG 5 [提示]：你身上的元宝不足。
MOV N32 0
MOV I34 0
GOTO @main
BREAK
#IF
EQUAL M44 2
#ACT
MOV N32 0
MOV I34 0
SENDMSG 5 [提示]：你已经下注甲方，不能在乙方下注了！
GOTO @main
BREAK
#IF
EQUAL M44 3
#ACT
MOV N32 0
MOV I34 0
SENDMSG 5 [提示]：你已经下注乙方，不能在乙方重复下注！
GOTO @main
#ELSEACT
MOV S23 乙方
MOV M44 3
MOV N33 <$STR(N32)>
MOV N34 <$STR(N33)>
GAMEGOLD - <$STR(N34)>
INC I16 <$STR(N33)>
INC I17 1
DEC I27 <$STR(N33)>
MOV I8 1
MOV I34 0
MOV N32 0
SENDMSG 6 你将<$STR(N34)>个元宝下注到【<$STR(S23)>】！祝你好运！！
GOTO @MAIN
[@游戏说明]
1) 如果只有一个玩家下注，2分钟后系统坐庄和下注的玩家比赛！ \
2) 下注的限制在10个元宝--10000个元宝之间！！ \
3) 下注的玩家下线将被视做弃权，损失下注元宝。 \
4) 比赛获胜的赔率是：买一赔一 如果甲乙同时战死算庄家赢！！ \
5) 比赛不限制参与者数量，参与的玩家越多越好！！！ \
6) 两只斗鸡比赛，最后没死的为胜方！同时战死算庄家赢！ \
7) 玩家下注完后可以留下观看比赛，也可以去做别的事情！ \
8) 赢方要交纳10%的税务！\
<返回/@main> <离开/@EXIT>
[@初始化]
#IF
IsAdmin
#ACT
MOV I8 0
MOV I9 2
MOV I10 120
MOV I14 0
MOV I15 0
MOV I16 0
MOV I17 0
MOV I18 60
MOV I19 0
MOV I20 0
MOV I21 0
MOV I22 0
MOV I23 0
MOV I24 0
MOV I25 0
MOV I26 0
MOV I27 0
MOV I28 0
MOV I32 0
MOV I33 0
MOV I34 0
MOV N30 0
MOV N31 0
MOV N32 0
MOV N33 0
MOV N34 0
MOV N35 0
MOV M44 0
MOV S23
MOV S240 <$USERNAME>
MOV A60 现在的庄家是【暂无】
MOV A61
CLEARMAPMON dns002
MapMove dns002 35 28
MONGENEX dns002 34 28 斗鸡(甲)|0|255 0 1
MONGENEX dns002 37 28 斗鸡(乙)|0|255 0 1
AUTOGOTOXY 36 28
SENDMSG 6 斗鸡初始化完成，你现在处于离线挂机状态！！
SendMSG 0 --------------------------------------------------------------
SendMSG 0 现在是抢庄时间，请抓紧时间！
SendMSG 0 --------------------------------------------------------------
;OFFLINEPLAY 14400 1
[@IsInFilterList]
#ACT
SENDMSG 5 [错误]：输入数据中包含了非法字符，请重新编辑！
