[@main]
#IF
Check [39] 0
#SAY
　　能来到这里足以证明英雄你的不凡，我这里珍藏着历代\
皇家收集的各种宝物，如果你能帮消灭一些来偷盗宝物的恶\
魔，我就让你在其中随机挑选一件。\\
　　<说吧，要让我做什么？/@任务>\
　　<兑换千万经验礼券/@兑换卷轴>\
　　<离开这里/@返回>
#ELSESAY
　　能来到这里足以证明英雄你的不凡，我这里珍藏着历代\
皇家收集的各种宝物，如果你能帮消灭一些来偷盗宝物的恶\
魔，我就让你在其中随机挑选一件。\\
　　<兑换千万经验礼券/@兑换卷轴>\
　　<离开这里/@返回>

[@任务]
到前面密室深处消灭一只尸霸后，再回来找我。\\
<我已经消灭了尸霸了/@消灭了>\\
<返回/@main>

[@返回]
　　你确定要离开这里返回到中州吗？\\
　　<是的，我想离开/@返回中州了>\
　　<返回/@main>

[@返回中州了]
#ACT
MAPMOVE 0 472 226
break

[@兑换卷轴]
你有千万经验礼券吗？有的话，可以在我这里兑换。\\
<我有，我要兑换千万经验礼券/@开始兑换了>\\
<没有/@exit>

[@开始兑换了]
#IF
Check [38] 1
#SAY
你已经兑换过一次了，请下次再来吧。\\
<离开/@exit>
#ACT
break
#IF
checkitem 千万经验礼券 1
#ACT
take 千万经验礼券 1
MOVR P1 3
INC P1
MUL P1 10000000
GIVE 经验 $STR(P1)
SET [38] 1
SENDMSG 5 恭喜你成功兑换到了<$STR(P1)>经验
SENDMSG 10 恭喜<$USERNAME>在黑暗殿堂密室守护者处成功使用千万经验礼券兑换到了<$STR(P1)>经验
#SAY
恭喜你本次成功兑换了<$STR(P1)>经验。\\
<谢谢/@exit>
#ELSESAY
你没有带来千万经验礼券，不能兑换。\\
<离开/@exit>

[@消灭了]
#IF
Check [40] 0
#SAY
你还没有把尸霸消灭，赶快行动吧，就在前面！\\
<离开/@exit>
#ACT
break
#IF
Check [39] 0
#ACT
ReadRandomStr ..\QuestDiary\数据文件\文本数据\黑暗殿堂奖品.txt S7
SET [39] 1
GIVE $STR(S7) 1
SENDMSG 10 恭喜<$USERNAME>在黑暗殿堂中发现了宝物，获得了<$STR(S7)>，完成恶魔城拯救公主任务，就能探索黑暗殿堂，丰富宝藏等你来拿
#SAY
这件宝贝就给你了，是好是坏都是你的运气决定：\\
你获得奖品：<$STR(S7)>\\
<谢谢/@exit>
#ELSESAY
你已经领取过一次礼物了，不要重复领取。\\
<离开/@exit>
#ELSEACT
break